バージョン 6.3.3	検索   索引   目次   |   PDF BOOKS   |   ホーム   上へ   戻る   次へ

MOVE ステートメントは、オペランドの値を 1 つ以上のオペランド（フィールドまたは配列）に移動するために使用します。

このドキュメントでは、次のトピックについて説明します。

• 機能

• 構文説明

• 例

関連ステートメント：ADD | COMPRESS | COMPUTE | DIVIDE | EXAMINE | MOVE ALL | MULTIPLY | RESET | SEPARATE | SUBTRACT

関連機能グループ：「算術演算とデータ移動操作」

機能

MOVE ステートメントは、オペランドの値を 1 つ以上のオペランド（フィールドまたは配列）に移動するために使用します。

複数のターゲットオペランドを持つ MOVE ステートメントは、対応する個々の MOVE ステートメントと同一です。

MOVE #SOURCE TO #TARGET1 #TARGET2

これは、以下と同じです。

MOVE #SOURCE TO #TARGET1 
MOVE #SOURCE TO #TARGET2

例：

DEFINE DATA LOCAL
1 #ARRAY(I4/1:3) INIT <3,0,9>
1 #INDEX(I4)
1 #RESULT(I4)
END-DEFINE
*
#INDEX := 1
MOVE #ARRAY(#INDEX) TO #INDEX       /* #INDEX is 3 
                       #RESULT      /* #RESULT is 9  
*
#INDEX := 2
MOVE #ARRAY(#INDEX) TO  #INDEX     /* #INDEX is 0
                        #ARRAY(3)  /* returns run time error NAT1316 

operand2 がダイナミック変数 変数のとき、その長さは MOVE 操作によって変更できます。 ダイナミック変数の現在の長さは、システム変数 *LENGTH を使用して確認できます。 ダイナミック変数については、『プログラミングガイド』の「ラージ変数／フィールドとダイナミック変数／フィールド」を参照してください。

operand2 のフォーマットが C の場合、operand1 は "(parameter)" として指定することもできます。 有効なパラメータは以下のとおりです。

データ転送の互換性および規則についての詳細は、『プログラミングガイド』の「データ転送」を参照してください。

その他の考慮事項

受け取りフィールドにデータベースフィールドが指定されても、MOVE 処理はプログラム内のフィールドの内部値を更新するだけで、 データベースのフィールドの値は変更しません。

AT BREAK、AT END OF DATA または AT END OF PAGE ステートメントとともに MOVE ステートメントが指定された場合にのみ Natural システム関数が使用できます。

『プログラミングガイド』の「演算割り当てのルール」も参照してください。

注意:
operand1 が時間変数（フォーマット T）のとき、変数内容の時間コンポーネントだけが転送され、日付コンポーネントは転送されません（構文 4 と構文 5 で説明されている MOVE EDITED の場合を除く）。

構文説明

このステートメントには異なる構造が可能です。

• 構文 1 - MOVE ROUNDED

• 構文 2 - MOVE SUBSTRING

• 構文 3 - MOVE BY NAME / POSITION

• 構文 4 - MOVE EDITED（operand2 で指定された編集マスク）

• 構文 5 - MOVE EDITED（operand1 で指定された編集マスク）

• 構文 6 - MOVE LEFT/RIGHT JUSTIFIED

• 構文 7 - MOVE NORMALIZED

• 構文 8 - MOVE ENCODED

次の構文図で使用されている記号については、「構文記号」を参照してください。

構文 1 - MOVE ROUNDED

MOVE [ROUNDED] operand1 [( parameter)] TO operand2

オペランド定義テーブル：

構文要素の説明：

MOVE 'XYZ' TO #A
MOVE #A (PM=I) TO #B

構文 2 - MOVE SUBSTRING

オペランド定義テーブル：

^* 説明を参照

構文要素の説明：

MOVE SUBSTRING(#A,5,8) TO #B

MOVE #A TO SUBSTRING(#B,3,4)

構文 3 - MOVE BY NAME / POSITION

オペランド定義テーブル：

構文要素の説明：

構文 4 - MOVE EDITED（operand2 で指定された編集マスク）

オペランド定義テーブル：

構文要素の説明：

MOVE EDITED operand1 TO operand2 (EM=value)

STACK TOP DATA operand1
INPUT operand2 (EM=value)

構文 5 - MOVE EDITED（operand1 で指定された編集マスク）

オペランド定義テーブル：

構文要素の説明：

MOVE EDITED operand1 (EM=value) TO operand2

WRITE operand1 (EM=value)

構文 6 - MOVE LEFT/RIGHT JUSTIFIED

オペランド定義テーブル：

構文要素の説明：

構文 7 - MOVE NORMALIZED

MOVE NORMALIZED ステートメントは、Unicode 文字列を "Unicode Normalization Form C"（NFC）に変換します。 結果として生成される Unicode 文字列には、構成前の文字として使用可能な文字の結合順序が含まれません。

ターゲットオペランドの形式が Unicode でない場合は、Unicode からターゲットオペランドへの暗黙的な変換が行われます。この変換中に、デフォルトのコードページ（システム変数「*CODEPAGE」を参照）が使用されます。

MOVE NORMALIZED ステートメントの詳細は、『Unicode およびコードページのサポート』ドキュメントの「ステートメント」を参照してください。

構文図：

オペランド定義テーブル：

構文要素の説明：

MOVE NORMALIZED #SCR TO #TGT

例：

一部のコードポイントは、異なる Unicode 表現を持ちます。 例えば、ドイツ語の文字 'Ä' では、Unicode の分解表現は U+0041 に続いて U+0308 であり、結合文字（U+0308）を使用します。代替表現は、構成前の文字 U+00C4 です。 MOVE NORMALIZED ステートメントは、可能な限り構成前の文字を使用して、結合文字を持つ Unicode 表現を正規化された Unicode 表現に変換します。

構文 8 - MOVE ENCODED

このセクションでは、MOVE ENCODED ステートメントの構文について説明します。 このステートメントの目的の詳細は、『Unicode およびコードページのサポート』ドキュメントの「ステートメント」を参照してください。

構文図：

オペランド定義テーブル：

構文要素の説明：

注意:

1. コードページオペランドが指定されていない場合は、現在のセッションのコードページ（システム変数 *CODEPAGE の値）がデフォルトとして使用されます。
2. ステートメント SET GLOBALS またはシステムコマンド GLOBALS のセッションパラメータ CPCVERR が ON に設定されている場合は、ソースフィールドの少なくとも 1 文字を目的のコードページに正しく変換できなかった場合にエラーが出力されますが、ターゲットフィールドでは置換文字で置換されます。

例：

MOVE ENCODED A-FIELD1 TO A-FIELD2

無効：コードページ名がデフォルトで取得され、operand1 と operand3 に対して同じであるため、構文エラーになります。

MOVE ENCODED A-FIELD1 CODEPAGE 'IBM01140' TO A-FIELD2 CODEPAGE 'IBM01140'

無効：コーディングされたコードページ名が operand1 と operand3 に対して同じであるため、エラーになります。

MOVE ENCODED A-FIELD1 CODEPAGE 'IBM01140' TO A-FIELD2 CODEPAGE 'IBM037'

有効：IBM01140 でコーディングされている A-FIELD1 の文字列は、IBM037 でコーディングされた A-FIELD2 に変換されます。

MOVE ENCODED U-FIELD TO U-FIELD

無効：少なくとも 1 つのオペランドが A または B の形式である必要があるため、エラーになります。

MOVE ENCODED U-FIELD TO A-FIELD

有効：UTF-16 でエンコードされるものとみなされる U-FIELD の Unicode 文字列は、デフォルトのコードページ（*CODEPAGE）の英数字 A-FIELD に変換されます。

MOVE ENCODED A-FIELD TO U-FIELD

有効：デフォルトのコードページ（*CODEPAGE）でエンコードされるものとみなされる A-FIELD の文字列は、Unicode フィールド U-FIELD に変換されます。

MOVE ENCODED A100-FIELD CODEPAGE 'IBM1140' TO A50-FIELD CODEPAGE 'IBM037'

有効：関連するコードページを使用して、A100-FIELD（フォーマット／長さ：A100）から A50-FIELD（フォーマット／長さ：A50）に変換されます。 ターゲットは切り捨てられます。 Natural エラーメッセージは返されません。

MOVE ENCODED A100-FIELD CODEPAGE 'IBM1140' TO A50-FIELD CODEPAGE 'IBM037' GIVING RC-FIELD

有効：関連するコードページを使用して、A100-FIELD（フォーマット／長さ：A100）から A50-FIELD（フォーマット／長さ：A50）に変換されます。 ターゲットは切り捨てられます。 GIVING 節が指定されていないため、RC-FIELD は、値の切り捨てが行われたことを示すエラーコードを受け取ります。

例

• 例 1 - MOVE ステートメントのさまざまな使用例

• 例 2 - MOVE BY NAME

• 例 3 - 配列を伴う MOVE BY NAME

• 例 4 - MOVE BY POSITION

例 1 - MOVE ステートメントのさまざまな使用例

** Example 'MOVEX1': MOVE                                               
************************************************************************
DEFINE DATA LOCAL                                                       
1 #A (N3)                                                               
1 #B (A5)                                                               
1 #C (A2)                                                               
1 #D (A7)                                                               
1 #E (N1.0)                                                             
1 #F (A5)                                                               
1 #G (N3.2)                                                             
1 #H (A6)                                                               
END-DEFINE                                                              
*                                                                       
MOVE 5 TO #A                                                            
WRITE NOTITLE 'MOVE 5 TO #A'      30X '=' #A                            
*                                                                       
MOVE 'ABCDE' TO #B #C #D                                                
WRITE 'MOVE ABCDE TO #B #C #D'    20X '=' #B '=' #C '=' #D              
*                                                                       
MOVE -1  TO #E                                             
WRITE 'MOVE -1  TO #E'            28X '=' #E               
*                                                          
MOVE ROUNDED 1.995 TO #E                                   
WRITE 'MOVE ROUNDED 1.995 TO #E'  18X '=' #E               
*                                                          
*                                                          
MOVE RIGHT JUSTIFIED 'ABC' TO #F                           
WRITE 'MOVE RIGHT JUSTIFIED ''ABC'' TO #F'       10X '=' #F
*                                                          
MOVE EDITED '003.45' TO #G (EM=999.99)                     
WRITE 'MOVE EDITED ''003.45'' TO #G (EM=999.99)'  4X '=' #G
*                                                          
MOVE EDITED 123.45 (EM=999.99) TO #H                      
WRITE 'MOVE EDITED 123.45 (EM=999.99) TO #H'      6X '=' #H
*                                                          
END                                   

プログラム MOVEX1 の出力：

MOVE 5 TO #A                              #A:    5                  
MOVE ABCDE TO #B #C #D                    #B: ABCDE #C: AB #D: ABCDE
MOVE -1  TO #E                            #E: -1                    
MOVE ROUNDED 1.995 TO #E                  #E:  2                    
MOVE RIGHT JUSTIFIED 'ABC' TO #F          #F:   ABC                 
MOVE EDITED '003.45' TO #G (EM=999.99)    #G:    3.45               
MOVE EDITED 123.45 (EM=999.99) TO #H      #H: 123.45            

例 2 - MOVE BY NAME

** Example 'MOVEX2': MOVE BY NAME                                       
************************************************************************
DEFINE DATA LOCAL                                                       
1 #SBLOCK                                                               
  2 #FIELDA (A10) INIT <'AAAAAAAAAA'>                                   
  2 #FIELDB (A10) INIT <'BBBBBBBBBB'>                                   
  2 #FIELDC (A10) INIT <'CCCCCCCCCC'>                                   
  2 #FIELDD (A10) INIT <'DDDDDDDDDD'>                                   
1 #TBLOCK                                                               
  2 #FIELD1 (A15) INIT <' '>                                            
  2 #FIELDA (A10) INIT <' '>                                            
  2 #FIELD2 (A10) INIT <' '>                                            
  2 #FIELDB (A10) INIT <' '>                                            
  2 #FIELD3 (A20) INIT <' '>                                            
  2 #FIELDC (A10) INIT <' '>                                            
END-DEFINE                                                              
*                                                                       
MOVE BY NAME #SBLOCK TO #TBLOCK                                      
*                                                                       
WRITE NOTITLE 'CONTENTS OF #TBLOCK AFTER MOVE BY NAME:'
       // '=' #TBLOCK.#FIELD1                          
        / '=' #TBLOCK.#FIELDA                          
        / '=' #TBLOCK.#FIELD2                          
        / '=' #TBLOCK.#FIELDB                          
        / '=' #TBLOCK.#FIELD3                          
        / '=' #TBLOCK.#FIELDC                          
*                                                      
END                                                   

MOVE BY NAME 処理後の #TBLOCK の内容：

CONTENTS OF #TBLOCK AFTER MOVE BY NAME:
                                       
#FIELD1:                               
#FIELDA: AAAAAAAAAA                    
#FIELD2:                               
#FIELDB: BBBBBBBBBB                    
#FIELD3:                               
#FIELDC: CCCCCCCCCC                   

例 3 - 配列を伴う MOVE BY NAME

DEFINE DATA LOCAL
  1 #GROUP1
    2 #FIELD (A10/1:10)
  1 #GROUP2
    2 #FIELD (A10/1:10)
END-DEFINE
... 
MOVE BY NAME #GROUP1 TO #GROUP2
...

この例では、MOVE ステートメントは内部的に次のように解決されます。

MOVE #GROUP1.#FIELD (*) TO #GROUP2.#FIELD (*)

添字付きグループの一部分が同一グループの他の部分に転送される場合、次の例のような予期しない結果となります。

DEFINE DATA LOCAL
  1 #GROUP1 (1:5)
    2 #FIELDA (N1) INIT <1,2,3,4,5>
    2 REDEFINE #FIELDA
      3 #FIELDB (N1)
END-DEFINE
...
MOVE BY NAME #GROUP1 (2:4) TO #GROUP1 (1:3)
...

この例では、MOVE ステートメントは内部的に次のように解決されます。

MOVE #FIELDA (2:4) TO #FIELDA (1:3)
MOVE #FIELDB (2:4) TO #FIELDB (1:3)

まず、#FIELDA のオカレンス 2 から 4 の内容は、#FIELDA のオカレンス 1 から 3 に移動されます。つまり、オカレンスは次の値を受け取ります。

#FIELDB のオカレンス 2 から 4 の内容は、#FIELDB のオカレンス 1 から 3 に移動されます。つまり、オカレンスは次の値を受け取ります。

例 4 - MOVE BY POSITION

DEFINE DATA LOCAL
  1 #GROUP1
    2 #FIELD1A (N5)
    2 #FIELD1B (A3/1:3)
    2 REDEFINE #FIELD1B
      3 #FIELD1BR (A9)
  1 #GROUP2
    2 #FIELD2A (N5)
    2 #FIELD2B (A3/1:3)
    2 REDEFINE #FIELD2B
      3 #FIELD2BR (A9)
END-DEFINE
...
MOVE BY POSITION #GROUP1 TO #GROUP2   
...

#FIELD1A の内容は、#FIELD2A に転送され、#FIELD1B の内容は、#FIELD2B に転送されます。フィールド #FIELD1BR と #FIELD2BR は影響を受けません。

www.softwareag.com

Copyright © Software AG 1992-2008. All rights reserved.

検索   索引   目次   |   PDF BOOKS   |   ホーム   上へ   戻る   次へ