In dieser Sitzung werden Sie das Beispiel-Programm PROG001 erstellen und ausführen, um die Wirkung des Statements INPUT USING MAP zu testen, das die Maske MAP001 aufruft.

Das Programm PROG001 ist in der Natural-System-Library SYSEXPG vorhanden. Wenden Sie sich wegen weiterer Einzelheiten an Ihren Natural-System-Administrator.

Um das Programm PROG001 zu erstellen und auszuführen:

1. Wenn Sie Zugriff auf eine Kopie des Programms PROG001 haben, geben Sie in der Kommandozeile des Menüs Edit Map Folgendes ein:

   EDIT PROG001

   Der Programm-Editor wird aufgerufen und der Quellcode des Programms PROG001 wird im Editier-Bereich angezeigt. Vergewissern Sie sich, dass das Programm mit dem weiter unten gezeigten Programm identisch ist.

   Oder:
   Falls Sie keinen Zugriff auf eine Kopie des Programms PROG001 haben, geben Sie in der Kommandozeile des Menüs Edit Map Folgendes ein:

   EDIT PROGRAM

   Der Programm-Editor wird aufgerufen. Falls erforderlich, löschen Sie den Inhalt des Editier-Bereichs durch Eingabe des Kommandos CLEAR am Eingabeaufforderungszeichen (>) des Programm-Editors.

   Geben Sie dann das folgende Programm ein:

   PROG001:

   ** Example 'PROG001': Example program for the Map Tutorial              
   ************************************************************************
    DEFINE DATA LOCAL                                                       
    01 PERS-VIEW VIEW OF EMPLOYEES                                          
      02 NAME                                                               
      02 FIRST-NAME                                                         
      02 CITY                                                               
    *                                                                       
    01 #NAME (A20)                                                          
    01 #CITY (A20)                                                          
    END-DEFINE                                                              
    *                                                                       
    REPEAT                                                                  
      /*                                                                    
      INPUT USING MAP 'MAP001'                                              
      /*                                                                    
      IF #CITY NE ' ' AND #NAME NE ' '                                      
        FIND PERS-VIEW WITH NAME = #NAME AND CITY = #CITY                   
          IF NO RECORDS FOUND
            REINPUT 'NO ONE BY THIS NAME LIVING IN THIS CITY.'
                    MARK *#CITY                               
          END-NOREC                                           
          /*                                                  
          DISPLAY NOTITLE NAME FIRST-NAME CITY                
          /*                                                  
        END-FIND                                              
      ELSE                                                    
        IF #NAME NE ' '                                       
          FIND PERS-VIEW WITH NAME = #NAME                    
            IF NO RECORDS FOUND                               
              REINPUT 'PLEASE TRY ANOTHER NAME.'              
            END-NOREC                                         
            /*                                                
            DISPLAY NOTITLE NAME FIRST-NAME CITY              
            /*                                                
          END-FIND                                            
        END-IF                                                
      END-IF
      /*               
    END-REPEAT         
    END

2. Falls in der obersten Zeile des Editors kein Programmname angezeigt wird, setzen Sie am Eingabeaufforderungszeichen (>) des Programm-Editors das Kommando STOW PROG001 ab.

   Oder:
   Wenn in der obersten Zeile des Editors der Programmname PROG001 angezeigt wird, setzen Sie am Eingabeaufforderungszeichen (>) des Programm-Editors das Kommando STOW ab.

   Falls erforderlich: Korrigieren Sie eventuell vorhandene Syntaxfehler und wiederholen Sie das Kommando STOW.

   Nachdem das Kommando STOW erfolgreich ausgeführt worden ist, wird das Programm als Source-Objekt und als katalogisiertes Objekt in der aktuellen Library in der aktuellen Systemdatei gespeichert.

3. Setzen Sie am Eingabeaufforderungszeichen (>) des Programm-Editors das folgende Kommando ab:

   RUN

   Das Programm PROG001 wird ausgeführt und die Maske MAP001 erscheint.

Um zu prüfen, ob die Maske MAP001 wie beabsichtigt funktioniert:

1. Drücken Sie Enter, ohne etwas einzutippen.

   Die folgende Meldung wird angezeigt: PLEASE TYPE IN A NAME.

2. Geben Sie im ersten Eingabefeld ein Fragezeichen (?) ein und drücken Sie Enter.

   Die Hilfe-Maske HELP001 erscheint.

3. Drücken Sie Enter.

   Die Hilfe-Maske verschwindet.

4. Geben Sie im ersten Eingabefeld den Namen MCKENNA ein und drücken Sie Enter.

   Die folgende Meldung wird angezeigt: PLEASE TRY ANOTHER NAME (Versuchen Sie es bitte mit einem anderen Namen.).

5. Ersetzen Sie MCKENNA durch JONES und drücken Sie Enter.

   Das Programm erzeugt die folgende Liste:

   NAME FIRST-NAME CITY -------------------- -------------------- -------------------- JONES VIRGINIA TULSA JONES MARSHA MOBILE JONES ROBERT MILWAUKEE JONES LILLY BEVERLEY HILLS JONES EDWARD CAMDEN JONES MARTHA KALAMAZOO JONES LAUREL BALTIMORE JONES KEVIN DERBY JONES GREGORY NOTTINGHAM

6. Drücken Sie Enter.

   Die Maske MAP001 erscheint

7. Geben Sie im ersten Eingabefeld der Maske den Namen JONES und im zweiten Eingabefeld den Namen DUNFERMLINE ein.

8. Drücken Sie Enter.

   Die folgende Meldung wird angezeigt: NO ONE BY THIS NAME LIVING IN THIS CITY (Es existiert niemand mit diesem Namen in dieser Stadt.).

9. Geben Sie im ersten Eingabefeld der Maske den Namen JONES und im zweiten Eingabefeld den Namen TULSA ein.

10. Drücken Sie Enter.

    Das Programm erzeugt die folgende Liste:

    NAME FIRST-NAME CITY -------------------- -------------------- -------------------- JONES VIRGINIA TULSA

11. Drücken Sie Enter.

    Die Maske MAP001 erscheint

12. Geben Sie im ersten Eingabefeld einen Punkt (.) ein und drücken Sie Enter.

    Der Editier-Bereich des Programm-Editors erscheint. Er enthält den Quellcode des Programms PROG001.

Sie können nun fortfahren mit Maske für WRITE erstellen und Feld-Definitionen kopieren.