READLOB

READLOB			ALL (operand1)			[IN] [FILE] view-name
[PASSWORD=operand2]
[CIPHER=operand3]
[[WITH] ISN [=] operand4]
[[STARTING] [AT] OFFSET [=] operand5]
statement
END-READLOB	（ストラクチャードモードのみ）
LOOP	（レポーティングモードのみ）

このドキュメントでは、次のトピックについて説明します。

• 関数

• 制限

• 構文説明

• READLOB で使用可能なシステム変数

• 機能上の考慮事項

• 例

構文図で使用されている記号については、「構文記号」を参照してください。

関連ステートメント：READ | FIND | GET | UPDATELOB

関連機能グループ：データベースへのアクセスと更新

関数

READLOB ステートメントは、単一レコードで使用します。そのレコードでは、定義された LOB フィールド（Large OBject フィールド）がループ処理中に固定長のセグメントで読み取られます。この LOB フィールドの読み取りにのみ適用されます。

ループ開始時に、LOB フィールド内のオフセットが最初のデータの取得元に設定されます。次のループの反復では、最後のセグメントに続くセグメントが返されます。LOB データエンドに到達すると、ループが終了します。

このステートメントでは、処理ループを開始します。『プログラミングガイド』の「ループ処理」も参照してください。

制限

READLOB ステートメントは、Adabas データベースにアクセスするためにのみ使用できます。

構文説明

オペランド定義テーブル：

* operand1 operand4 および operand5 のフォーマット B は、4 以下の長さでのみ使用できます。

構文要素の説明：

READLOB (5) IN FILE VIEW01 ...

#CNT := 10
READLOB (#CNT) IN FILE VIEW01 ...

READLOB で使用可能なシステム変数

Natural システム変数 *ISN、*COUNTER および *NUMBER が READLOB ステートメントで提供されます。

これらのシステム変数は、P10 のフォーマットと長さで定義されています。このフォーマット／長さは変更できません。

READLOB ステートメントとともに使用する場合の Natural システム変数の目的は、次のとおりです。

機能上の考慮事項

• READLOB ステートメントは常に、ホールド状態にないレコードを読み取ります。LOB データの安定性を保証するため（つまり、他のユーザーによる更新を防止するため）、READLOB がLOB フィールドを参照している間、データベースステートメントでレコードをホールド状態に設定し、ISN を以下のいずれかに設定できます

  • UPDATE または DELETE が外部 READ または FIND ステートメントを参照しているため、排他的ホールドに設定、または

  • READ または FIND ステートメントで適用される明示的な IN SHARED HOLD オプションにより共有ホールドに設定。追加のサブパラメータ MODE=Q が使用されている場合、読み取りシーケンスで次のレコードがフェッチされると、レコードは自動的にホールドからリリースされます。

• READLOB ステートメントは常に、ホールド状態にないレコードを読み取るため、UPDATE、DELETE または GET SAME ステートメントは READLOB ステートメントを参照してはいけません。

例

• 例 1 - READ ループからのレコード番号の取得

• 例 2 - ユーザー定義の値によるレコード番号の取得

• 例 3 - READ ループからのレコード番号の取得（排他的ホールドあり）

例 1 - READ ループからのレコード番号の取得

DEFINE DATA LOCAL
1 VIEW01 VIEW OF ..
  2 NAME 
  2 L@LOBFIELD
1 VIEW02 VIEW OF ..
  2 LOBFIELD_SEGMENT                /* LOB field defined in DDM with (A1000).
END-DEFINE
*
READ VIEW01 BY NAME = 'SMITH'       /* Outer statement reads all demanded record 
                                    /* fields, except the LOB field.
     IN SHARED HOLD MODE=Q          /* Set record into shared hold to enforce LOB 
                                    /* data stability during READLOB.
  DISPLAY NAME 'Total-length LOB-field' L@LOBFIELD 
  READLOB VIEW02                    /* Record number used from active record of 
                                    /* READ statement.
                                    /* LOB is read in segments with length 1000. 
      STARTING AT OFFSET = 2000     /* Start to read the LOB field at byte 2000.
    WRITE 'Loop counter:' *COUNTER  10X ' Next offset:' *NUMBER
    PRINT VIEW02.LOBFIELD_SEGMENT  
  END-READLOB
END-READ   
END

例 2 - ユーザー定義の値によるレコード番号の取得

DEFINE DATA LOCAL
1 #ISN  (I4)
1 #CNT  (I4)
1 #OFF  (I4)
1 VIEW02 VIEW OF ..
  2 LOBFIELD_SEGMENT            /* LOB field defined in DDM with (A1000).
END-DEFINE
*
INPUT (AD=T)
  / ' Read record (ISN):' #ISN
  / 'Number of segments:' #CNT
  / '   Start at offset:' #OFF
* 
READLOB (#CNT) VIEW02           /* Read max. (#CNT) segments with length 1000.
    WITH ISN = #ISN             /* Record number provided by user.
                                /* Record is not in hold.
    STARTING AT OFFSET = #OFF   /* Start to read the LOB field at byte (#OFF).
  WRITE 'Loop counter:' *COUNTER  10X ' Next offset:' *NUMBER
  PRINT VIEW02.LOBFIELD_SEGMENT  
END-READLOB
END

例 3 - READ ループからのレコード番号の取得（排他的ホールドあり）

DEFINE DATA LOCAL
1 VIEW01 VIEW OF ..
  2 NAME 
1 VIEW02 VIEW OF ..
  2 LOBFIELD_SEGMENT           /* LOB field defined in DDM with (A1000).
END-DEFINE
*
R1. READ VIEW01 BY NAME = 'SMITH'/* Outer statement reads all demanded  
                                 /* record fields, except the LOB field.
  DISPLAY NAME 
  READLOB VIEW02            /* Record number from active record of READ.
                            /* LOB is read in segments with length 1000. 
      STARTING AT OFFSET = 2000 /* Start to read LOB field at byte 2000. 
    WRITE 'Loop counter:' *COUNTER 10X ' Next offset:' *NUMBER
    PRINT VIEW02.LOBFIELD_SEGMENT  
  END-READLOB
  ...
  UPDATE (R1.)            /* Set record into exclusive hold that 
                          /* enforces LOB data stability during READLOB.
  END OF TRANSACTION
END-READ   
END