Dieses Dokument behandelt die folgenden Themen:
Eine Dokumentliste anzeigen.
Dieses Subprogramm entspricht Z-DIS11X mit der Ausnahme, dass es auch den Parameter Antwort ausgibt.
Sie können entweder alle Dokumente eines Büros in alphabetischer Reihenfolge anzeigen (steigend oder absteigend) oder alle Dokumente eines Fachs/Ordners in chronologischer Reihenfolge (steigende, absteigende oder freie Ablagefolge).
Um eine Liste aller Dokumente eines Büros anzuzeigen, dürfen Sie kein Fach und keinen Ordner angeben.
Sie können ein Fach oder einen Ordner entweder über seine Nummer oder seinen Namen angeben. Sie dürfen nicht beides angeben.
Anmerkung:
Vor dem Aufruf dieses Subprogramms können Sie
Z-DIS13 aufrufen, um die Nummer eines
selbstdefinierten Fachs auszugeben.
Dokumente in den Fächern Papierkorb, Posteingang oder Tageskopien werden nur dann angezeigt, wenn der Parameter Fachname oder Fachnummer angegeben wird.
Für eine alphabetische oder freie Ablagefolge können Sie einen Dokumentnamen im Parameter Startwert angeben. Für eine steigende oder absteigende Ablagefolge können Sie ein Dokumentdatum im Parameter Startwert angeben.
Eine vollständige Dokumentliste wird ausgegeben, wenn Sie dieses Subprogramm iterativ aufrufen. Nachdem Sie das Subprogramm aufgerufen haben, können Sie die Parameter nicht mehr ändern. Wenn Sie dieses Subprogramm iterativ aufrufen, enthält der Work-Parameter die erforderlichen Werte für den erneuten Aufruf.
Der Parameter Absender-/Empfaengername wird nur für Dokumente ausgegeben, die sich in den Fächern Posteingang und Tageskopien befinden.
Anmerkung:
Wenn Sie das Fach Posteingang oder die Fachnummer 1 angeben, ohne
eine Ordnernummer oder einen Ordnernamen anzugeben, gibt dieses Subprogramm
eine Liste aller Dokumente in allen Ordnern des Fachs Posteingang aus.
| Parameter | Format | Ein | Aus | Bemerkung |
|---|---|---|---|---|
| Return-Code | N2 | O | X | Eingabe -1: kein ET. |
| Buero | A8 | E | Der Name des Büros, in dem Sie die Dokumentliste anzeigen wollen. | |
| Passwort | A8 | E | Das Passwort des o.g. Büros. | |
| Fachname | A15 | O* | Der Name des Fachs, in dem Sie die Dokumentliste anzeigen wollen. Entweder Fachname oder Fachnummer, nicht beides. | |
| Ordnername | A15 | O* | Der Name des Ordners, in dem Sie die Dokumentliste anzeigen wollen. Entweder Ordnername oder Ordnernummer, nicht beides. | |
| Fachnummer | N5 | O* | Die Nummer des Fachs, in dem Sie die Dokumentliste anzeigen wollen. Entweder Fachnummer oder Fachname, nicht beides. Siehe Fachnummern. | |
| Ordnernummer | N5 | O* | Die Nummer des Ordners, in dem Sie die Dokumentliste anzeigen wollen. Entweder Ordnernummer oder Ordnername, nicht beides. Siehe Ordnernummern . | |
| Ablagefolge | N1 | O | Wenn einer der Fach-/Ordnerparameter angegeben wurde: 1 (Datum steigend), 2 (Datum absteigend) oder 3 (freie Ablagefolge). Wenn keiner der Fach-/Ordnerparameter angegeben wurde: 1 (Name steigend) oder 2 (Name absteigend). Vorgabe: 1. | |
| Startwert | A32 | O | Für alphabetische oder freie Ablagefolge: Dokumentname. Für steigende oder absteigende Ablagefolge: Dokumentdatum (yyyymmdd). | |
| Anzahl | N2 | O | Die maximale Anzahl von Dokumenten, die mit jedem Aufruf ausgegeben werden. Wenn Sie keinen Wert definieren oder einen Wert, der größer ist als 20, wird der Vorgabewert 20 benutzt. | |
| Dokumentliste (20) | ||||
| ISN | P10 | X | Die ISN des Dokuments. | |
| Dokumentname | A32 | X | Der Name des Dokuments. | |
| Beschreibung | A60 | X | Die erste Zeile der Beschreibung. | |
| Dokumentformat | A1 | X | Siehe Dokumentformate. | |
| Abgelegt-in-Ordner | A15 | X | Der Name des Ordners, in dem das Dokument abgelegt ist. | |
| Datum-abgelegt | N8 | X | Das Datum, an dem das Dokument in diesem Büro abgelegt wurde. Wenn sich das Dokument im Fach Posteingang oder Tageskopien befindet, ist dies das Datum, an dem das Dokument gesendet wurde. | |
| Absender-/Empfaengername | A20 | X | Wenn sich das Dokument im Fach Posteingang befindet, ist dies der Name des Absenders. Wenn sich das Dokument im Fach Tageskopien befindet, ist dies der Name des ersten Empfängers. | |
| Postzaehler | N7 | X | Wenn sich das Dokument im Fach Tageskopien befindet, ist dies die Anzahl der Empfänger, an die das Dokument gesendet wurde. | |
| Antwort | A1 | X | Ein Stern (*) bedeutet, dass eine Antwort auf erhaltene Post gesendet wurde (Posteingang) oder dass eine Antwort auf versendete Post eingegangen ist (Tageskopien). Ein Fragezeichen (?) bedeutet, dass eine Antwort bereits erstellt, aber noch nicht gesendet wurde (Posteingang). | |
| Work-Parameter | A49 | Für den internen Gebrauch. Siehe Work-Parameter. | ||
| 00 | Erfolg |
| 02 | Ungültiger Büroname oder - nur im Batch-Betrieb - Büro gesperrt |
| 03 | Falsches Passwort |
| 11 | Geben Sie Fach-/Ordnername oder Nummer ein - nicht beides |
| 55 | Das gewünschte Fach bzw. der gewünschte Ordner existiert nicht |
| 73 | Ungültiger Fach-/Ordnername |
| 77 | Ende der Liste |
Z-120
Z-122
Z-123
Z-147
Z-150
Z-175
Z-1200&0
* Dokumentliste zeigen
*
DEFINE DATA
LOCAL
1 RETURN-CODE (N2)
1 BUERO (A8)
1 PASSWORT (A8)
1 FACHNAME (A15)
1 ORDNERNAME (A15)
1 FACHNUMMER (N5)
1 ORDNERNUMMER (N5)
1 ABLAGEFOLGE (N1)
1 STARTWERT (A32)
1 REDEFINE STARTWERT
2 STARTDATUM (A8)
1 ANZAHL (N2)
1 DOKUMENTLISTE (20)
2 ISN (P10)
2 DOKUMENTNAME (A32)
2 BESCHREIBUNG (A60)
2 DOKUMENTFORMAT (A1)
2 ABGELEGT-IN-ORDNER (A15)
2 DATUM-ABGELEGT (N8)
2 ABSENDER-EMPFAENGER-NAME (A20)
2 POSTZAEHLER (N7)
2 ANTWORT (A1)
1 WORK-PARAMETER (A49)
1 #INDEX (N2)
*
END-DEFINE
*
RESET RETURN-CODE
MOVE 'BUERO' TO BUERO
MOVE 'PASSWORT' TO PASSWORT
MOVE 'Arbeitsfach' TO FACHNAME
MOVE 2 TO ABLAGEFOLGE
MOVE '20020202' TO STARTDATUM
MOVE 20 TO ANZAHL
*
REPEAT UNTIL RETURN-CODE NE 0
*
CALLNAT 'Z-DIS11A'
RETURN-CODE
BUERO
PASSWORT
FACHNAME
ORDNERNAME
FACHNUMMER
ORDNERNUMMER
ABLAGEFOLGE
STARTWERT
ANZAHL
DOKUMENTLISTE(*)
WORK-PARAMETER
*
FOR #INDEX 1 TO ANZAHL
IF ISN(#INDEX) NE 0
WRITE NOTITLE (SG=OFF ZP=OFF AD=L)
'=' #INDEX
/ 'Dokumentname ' DOKUMENTNAME(#INDEX)
/ 'Beschreibung ' BESCHREIBUNG(#INDEX) (AL=40)
/ 'Dokumentformat ' DOKUMENTFORMAT(#INDEX)
/ 'Abgelegt in Ordner ' ABGELEGT-IN-ORDNER(#INDEX)
/ 'Abgelegt am ' DATUM-ABGELEGT(#INDEX)
/ 'Absender ' ABSENDER-EMPFAENGER-NAME(#INDEX)
/ 'Anzahl Empfaenger ' POSTZAEHLER(#INDEX)
/ 'Antwort ' ANTWORT(#INDEX)
NEWPAGE
END-IF
END-FOR
END-REPEAT
*
WRITE 'Return-Code ' RETURN-CODE
*
END