GET TRANSACTION DATA

#### Search Results

Search

# GET TRANSACTION DATA

`GET TRANSACTION` [`DATA`] operand1

This document covers the following topics:

- GET TRANSACTION DATA Usage

- Restriction

- GET TRANSACTION DATA Syntax Description

- GET TRANSACTION DATA Example

For an explanation of the symbols used in the syntax diagram, see Syntax Symbols.

Related Statements: `ACCEPT/REJECT` | `AT BREAK` | `AT START OF DATA` | `AT END OF DATA` | `BACKOUT TRANSACTION` | `BEFORE BREAK PROCESSING` | `DELETE` | `END TRANSACTION` | `FIND` | `GET` | `GET SAME` | `HISTOGRAM` | `LIMIT` | `PASSW` | `PERFORM BREAK PROCESSING` | `READ` | `RETRY` | `STORE` | `UPDATE`

Belongs to Function Group: Database Access and Update

## GET TRANSACTION DATA Usage

The `GET TRANSACTION DATA` statement is used to read the data saved with a previous `END TRANSACTION` statement.

`GET TRANSACTION DATA` does not create a processing loop.

### System Variable *ETID

The content of the Natural system variable `*ETID` identifies the transaction data to be retrieved from the database.

### No Transaction Data Stored

If the `GET TRANSACTION DATA` statement is issued and no transaction data are found, all fields specified in the `GET TRANSACTION DATA` statement will be filled with blanks regardless of format definition.

| Warning: Make sure that arithmetic operations are not performed on "empty" transaction data, because this would result in an abnormal termination of the program.

## Restriction

The `GET TRANSACTION DATA` statement is only valid for transactions applied to Adabas databases.

## GET TRANSACTION DATA Syntax Description

Operand Definition Table:

Operand | Possible Structure | Possible Formats | Referencing Permitted | Dynamic Definition
--- | --- | --- | --- | ---
`operand1` |  | S |  |  |  | A | U | N | P | I | F | B | D | T |  |  |  |  | yes | yes

Syntax Element Description:

Syntax Element | Description
--- | ---
`operand1` | Field Specification: The sequence, lengths, and formats of the fields used in the `GET TRANSACTION DATA` statement must be identical to the sequence, lengths, and formats of the fields specified with the corresponding `END TRANSACTION` statement. Note `GET TRANSACTION DATA` cannot be used if `operand1` is a dynamic variable.

## GET TRANSACTION DATA Example

    ** Example 'GTREX1': GET TRANSACTION
    **
    ** CAUTION: Executing this example will modify the database records!
    ************************************************************************
    DEFINE DATA LOCAL
    1 EMPLOY-VIEW VIEW OF EMPLOYEES
      2 PERSONNEL-ID
      2 NAME
      2 FIRST-NAME
      2 MIDDLE-I
      2 CITY
    *
    1 #PERS-NR (A8) INIT <' '>
    END-DEFINE
    *
    GET TRANSACTION DATA #PERS-NR
    IF #PERS-NR NE ' '
      WRITE 'LAST TRANSACTION PROCESSED FROM PREVIOUS SESSION' #PERS-NR
    END-IF
    *
    REPEAT
      /*
      INPUT  10X 'ENTER PERSONNEL NUMBER TO BE UPDATED:' #PERS-NR
      IF #PERS-NR = ' '
        STOP
      END-IF
      /*
      FIND EMPLOY-VIEW WITH PERSONNEL-ID = #PERS-NR
        IF NO RECORDS FOUND
          REINPUT 'NO RECORD FOUND'
        END-NOREC
        INPUT (AD=M) PERSONNEL-ID (AD=O)
                   / NAME
                   / FIRST-NAME
                   / CITY
        UPDATE
        END TRANSACTION #PERS-NR
      END-FIND
      /*
    END-REPEAT
    END

### On this page

- GET TRANSACTION DATA Usage
- Restriction
- GET TRANSACTION DATA Syntax Description
- GET TRANSACTION DATA Example