DOWNLOAD PC FILE

DOWNLOAD

PC

[FILE] work-file-number

[VARIABLE] operand1

WRITE WORK COMMAND operand2

SYNC

ASYNC

Dieses Dokument behandelt folgende Themen:

Eine Erläuterung der in dem Syntax-Diagramm verwendeten Symbole entnehmen Sie dem Abschnitt Syntax-Symbole.

Verwandte Statements: CLOSE PC FILE | UPLOAD PC FILE | WRITE WORK FILE

Funktion

Dieses Statement dient dazu, Daten von einer Großrechner-Plattform zum PC zu übertragen.

Siehe auch die Natural Connection- und Entire Connection-Dokumentation

Syntax-Beschreibung

Operanden-Definitionstabelle:

Operand Mögliche Struktur Mögliche Formate Referenzierung erlaubt Dynam. Definition
operand1 C S A G   A U N P I F B D T L C ja nein
operand2 C S       A                     ja ja

Die Formate C und G sind bei Natural Connection nicht gültig.

Syntax-Element-Beschreibung:

Syntax-Element Beschreibung
work-file-number
Zu benutzende Arbeitsdateinummer:

Diese Nummer muss der Nummer unter den Arbeitsdateinummern für den PC entsprechen, wie sie in Natural definiert sind.

VARIABLE
Format:

Die Datensätze in der PC-Datei werden in variablem Format geschrieben. Beachten Sie, dass variable Datensätze nicht in PC Spreadsheet-Formate konvertiert werden können.

operand1
Feld-Spezifikation:

Mit operand1 geben Sie die Felder an, die zum PC heruntergeladen werden sollen.

COMMAND
COMMAND-Klausel:

Mit dieser Klausel können Sie PC-Kommandos (d.h. Kommandos, die in die Kommandozeile von Entire Connection auf dem PC eingegeben werden können) vom Großrechner zum PC senden.

Entire Connection überprüft, ob das gesendete Kommando gültig ist oder nicht. Ein Kommando, das vom PC nicht erkannt werden kann, wird zurückgewiesen. In diesem Fall gibt Natural eine Fehlermeldung mit dem Inhalt aus, dass das heruntergeladene Kommando vom PC zurückgewiesen wurde.

Sie können die COMMAND-Klausel benutzen, um zum Beispiel Entire Connection-Tasks vom Großrechner aus auszuführen. Wenn Sie die Task DIR haben, die PC Directory-Informationen anzeigt, können Sie diese direkt aus Ihrem Natural-Programm heraus auf dem Großrechner mit dem folgenden Statement anstoßen: 

DOWNLOAD PC FILE 7 COMMAND 'DIR'

In Beispiel 2 weiter unten wird die COMMAND-Klausel benutzt, um den Namen der PC-Datei zu definieren, die die heruntergeladenen Daten aufnehmen soll. Auf diese Art können Sie die Eingabeaufforderung nach dem Namen der Datei umgehen.

operand2
COMMAND-Spezifikation:

Mit operand2 geben Sie das DOS-Kommando oder die Entire Connection-Task an, die auf dem PC ausgeführt werden soll. operand2 muss eine alphanumerische Konstante oder Variable sein.

SYNC
ASYNC

Kontrollübergabe:

Mit SYNC geben Sie an, dass der PC nach Ausführen und Beenden von COMMAND die Kontrolle an Natural zurückgibt.

SYNC kann benutzt werden, um zum Beispiel sicherzustellen, dass das Kommando SET PCFILE ausgeführt worden ist, bevor eine Datei-Übertragung startet.

Mit ASYNC geben Sie an, dass der PC die Kontrolle sofort an Natural übergibt, ungeachtet der Tatsache, ob die Ausführung von COMMAND beendet wurde oder nicht.

Beispiele

Beispiel 1 — Benutzung des Statements DOWNLOAD PC FILE

Das folgende Programm veranschaulicht die Benutzung des Statements DOWNLOAD PC FILE. Die Daten werden zunächst selektiert und dann mittels Arbeitsdatei PC FILE 7 zum PC heruntergeladen. 

** Example 'PCDOEX1': DOWNLOAD PC FILE                                  
**                                                                      
** NOTE: Example requires that Natural Connection is installed.         
************************************************************************
DEFINE DATA LOCAL                                                       
01 PERS VIEW OF EMPLOYEES                                               
  02 PERSONNEL-ID                                                       
  02 NAME                                                               
  02 CITY                                                               
END-DEFINE                                                              
*                                                                       
FIND PERS WITH CITY = 'NEW YORK'                     /* Data selection         
  DOWNLOAD PC FILE 7 CITY NAME PERSONNEL-ID    /* Data download  
END-FIND                                                                
END

Ausgabe des Programms PCDOEX1:

Wenn Sie das Programm starten, erscheint ein Fenster, in dem Sie den Namen der PC-Datei angeben, in die die Daten heruntergeladen werden sollen. Die Daten werden dann auf den PC heruntergeladen.

Beispiel 2 — Benutzung der COMMAND-Klausel

Das folgende Programm veranschaulicht die Benutzung der COMMAND-Klausel im Statement DOWNLOAD PC FILE. Der Name der empfangenden PC-Datei wird als erstes definiert. Dann werden die Daten selektiert und auf diese Datei heruntergeladen. 

** Example 'PCDOEX2': DOWNLOAD PC FILE                                  
**                                                                      
** NOTE: Example requires that Natural Connection is installed.         
************************************************************************
DEFINE DATA LOCAL                                                       
01 PERS VIEW OF EMPLOYEES                                               
  02 PERSONNEL-ID                                                       
  02 NAME                                                               
  02 CITY                                                               
01 CMD (A80)                                   /* Variable for transfer 
END-DEFINE                                     /* of the PC command     
*                                                                       
MOVE 'SET PCFILE 7 DOWN DATA PERS.NCD' TO CMD  /* PC command to define  
*                                                                       
DOWNLOAD PC FILE 6 COMMAND CMD                 /* Command download
*                                                                       
FIND PERS WITH CITY = 'NEW YORK'               /* Data selection   
  DOWNLOAD PC FILE 7 CITY NAME PERSONNEL-ID    /* Data download         
END-FIND                                                                
END

Anmerkung:
Die PC-Dateinummern in zwei aufeinanderfolgenden DOWNLOAD PC FILE-Statements müssen sich unterscheiden.

Ausgabe des Programms PCDOEX2:

Wenn Sie das Programm starten, werden die Daten zu der PC-Datei heruntergeladen, die im Programm angegeben wurde. Ein Fenster erscheint nicht.