ユーザーコメントとは、ソースコードのステートメント間に追加または挿入する記述や説明メモのことです。これらの情報は、自分以外のプログラマによって作成または変更されたソースコードの理解や管理に特に有効です。また、コメント開始を示す文字列は、テストのためにステートメントの機能や複数のソースコード行を一時的に無効にするために使用することもできます。

Natural でソースコードにコメントを入力するには、以下の 2 つの方法があります。

• ソースコード行全体をコメントとして使用する方法

• ソースコード行の途中からコメントとして使用する方法

---

ソースコード行全体をコメントとして使用する方法

ソースコード行全体をユーザーコメントとして使用する場合、行の先頭に以下の 1 つを入力します。

• アスタリスクと空白（* ）

• 2 つのアスタリスク（**）

• スラッシュとアスタリスク（/*）

*  USER COMMENT
** USER COMMENT
/* USER COMMENT

例：

以下の例のように、コメント行は、ソースコードの構造を明確にするために使用することもできます。

** Example 'LOGICX03': BREAK option in logical condition
************************************************************************
DEFINE DATA LOCAL
1 EMPLOY-VIEW VIEW OF EMPLOYEES
  2 NAME
  2 FIRST-NAME
  2 BIRTH
*
1 #BIRTH (A8)
END-DEFINE
*
LIMIT 10
READ EMPLOY-VIEW BY BIRTH
  MOVE EDITED BIRTH (EM=YYYYMMDD) TO #BIRTH
  /*
  IF BREAK OF #BIRTH /6/
    NEWPAGE IF LESS THAN 5 LINES LEFT
    WRITE / '-' (50) /
  END-IF
  /*
  DISPLAY NOTITLE BIRTH (EM=YYYY-MM-DD) NAME FIRST-NAME 
END-READ 
END

ソースコード行の途中からコメントとして使用する方法

ソースコード行の途中からのみをユーザーコメントとして使用する場合、空白、スラッシュ、およびアスタリスク（ /*）を入力すると、行内のこの表記以降の部分がコメントとしてマークされます。

ADD 5 TO #A         /* USER COMMENT

例：

** Example 'LOGICX04': IS option as format/length check
************************************************************************
DEFINE DATA LOCAL
1 #FIELDA (A10)          /* INPUT FIELD TO BE CHECKED
1 #FIELDB (N5)           /* RECEIVING FIELD OF VAL FUNCTION
1 #DATE   (A10)          /* INPUT FIELD FOR DATE
END-DEFINE
*
INPUT #DATE #FIELDA
IF #DATE IS(D)
  IF #FIELDA IS (N5)
    COMPUTE #FIELDB = VAL(#FIELDA)
    WRITE NOTITLE 'VAL FUNCTION OK' //  '=' #FIELDA '=' #FIELDB
  ELSE
    REINPUT 'FIELD DOES NOT FIT INTO N5 FORMAT'
            MARK *#FIELDA
  END-IF
ELSE
  REINPUT 'INPUT IS NOT IN DATE FORMAT (YY-MM-DD) '
          MARK *#DATE
END-IF
*
END