Benutzerkommentare

Benutzerkommentare sind zu den Statements des Quellcodes hinzugefügte oder in ihnen verteilte Beschreibungen oder erläuternde Anmerkungen. Solche Informationen können besonders hilfreich sein, wenn es um das Verstehen und die Pflege von Quellcode geht, der von einem anderen Programmierer geschrieben oder editiert wurde.

Des Weiteren können die den Anfang eines Kommentars markierenden Zeichen benutzt werden, um die Funktion eines Statements oder mehrere Quellcode-Zeilen zu Test-Zwecken zeitweilig auszuschalten.

Sie haben in Natural verschiedene Möglichkeiten, im Quellcode Kommentare einzufügen.

Ganze Quellcode-Zeile als Kommentarzeile benutzen

Falls Sie eine ganze Quellcode-Zeile als Kommentarzeile verwenden möchten, geben Sie am Anfang der Zeile Folgendes ein:

  • einen Stern und ein Leerzeichen (*),

  • zwei Sterne (**) oder

  • einen Schrägstrich und einen Stern (/*). 

*  USER COMMENT
** USER COMMENT
/* USER COMMENT

Beispiel:

Wie dem folgenden Beispiel zu entnehmen ist, können Kommentarzeilen auch benutzt werden, um den Quellcode klar zu strukturieren. 

** Example 'LOGICX03': BREAK option in logical condition
************************************************************************
DEFINE DATA LOCAL
1 EMPLOY-VIEW VIEW OF EMPLOYEES
  2 NAME
  2 FIRST-NAME
  2 BIRTH
*
1 #BIRTH (A8)
END-DEFINE
*
LIMIT 10
READ EMPLOY-VIEW BY BIRTH
  MOVE EDITED BIRTH (EM=YYYYMMDD) TO #BIRTH
  /*
  IF BREAK OF #BIRTH /6/
    NEWPAGE IF LESS THAN 5 LINES LEFT
    WRITE / '-' (50) /
  END-IF
  /*
  DISPLAY NOTITLE BIRTH (EM=YYYY-MM-DD) NAME FIRST-NAME 
END-READ 
END

Teil einer Quellcode-Zeile als Kommentarzeile benutzen

Falls Sie nur einen Teil einer Quellcode-Zeile für einen Kommentar verwenden möchten, geben Sie ein Leerzeichen, einen Schrägstrich und einen Stern ( /*) ein; der Rest der Zeile ab dieser Markierung ist damit als Kommentar gekennzeichnet: 

ADD 5 TO #A         /* USER COMMENT

Beispiel: 

** Example 'LOGICX04': IS option as format/length check
************************************************************************
DEFINE DATA LOCAL
1 #FIELDA (A10)          /* INPUT FIELD TO BE CHECKED
1 #FIELDB (N5)           /* RECEIVING FIELD OF VAL FUNCTION
1 #DATE   (A10)          /* INPUT FIELD FOR DATE
END-DEFINE
*
INPUT #DATE #FIELDA
IF #DATE IS(D)
  IF #FIELDA IS (N5)
    COMPUTE #FIELDB = VAL(#FIELDA)
    WRITE NOTITLE 'VAL FUNCTION OK' //  '=' #FIELDA '=' #FIELDB
  ELSE
    REINPUT 'FIELD DOES NOT FIT INTO N5 FORMAT'
            MARK *#FIELDA
  END-IF
ELSE
  REINPUT 'INPUT IS NOT IN DATE FORMAT (YY-MM-DD) '
          MARK *#DATE
END-IF
*
END