In dieser Sitzung erstellen Sie und führen Sie das Beispiel-Programm PROG002 aus, um die Wirkung des Statements WRITE USING MAP zu testen, das die Masken MAP002 und MAP003 aufruft.

Um das Programm PROG002 zu erstellen:

1. Geben Sie in der Kommandozeile des Menüs Edit Map Folgendes ein:

   EDIT PROG002

   Der Programm-Editor wird aufgerufen und der Quellcode des Programms PROG002 wird im Editier-Bereich angezeigt.

2. Setzen Sie am Eingabeaufforderungszeichen (>) des Programm-Editors das folgende Kommando ab:

   SAVE PROG002

   Eine Kopie des Programms PROG001 wird als Source-Objekt unter dem Namen PROG002 in der aktuellen Natural-Library in der aktuellen Systemdatei gespeichert.

3. Setzen Sie am Eingabeaufforderungszeichen (>) des Programm-Editors das folgende Kommando ab:

   READ PROG002

   Der Quellcode des Programms PROG002 wird im Editier-Bereich des Programm-Editors angezeigt.

4. Ersetzen Sie die DISPLAY-Statements durch die unten fett hervorgehoben gezeigten Zeilen:

   PROG002:

   ** Example 'PROG002': Example program for the Map Tutorial              
   ************************************************************************
   DEFINE DATA LOCAL                                                       
   01 PERS-VIEW VIEW OF EMPLOYEES                                          
     02 NAME                                                               
     02 FIRST-NAME                                                         
     02 CITY                                                               
   *                                                                       
   01 #NAME (A20)                                                          
   01 #CITY (A20)                                                          
   END-DEFINE                                                              
   *                                                                       
   REPEAT                                                                  
     /*                                                                    
     INPUT USING MAP 'MAP001'                                              
     /*                                                                    
     IF #CITY NE ' ' AND #NAME NE ' '                                      
       FIND PERS-VIEW WITH NAME = #NAME AND CITY = #CITY                   
         IF NO RECORDS FOUND                                               
           REINPUT 'NO ONE BY THIS NAME LIVING IN THIS CITY.'
                   MARK *#CITY                         
         END-NOREC                                     
         /*                                            
         AT START OF DATA                              
           WRITE 'THE FOLLOWING EMPLOYEES LIVE IN' CITY
         END-START                                     
         WRITE USING MAP 'MAP003'                      
         /*                                            
       END-FIND                                        
     ELSE                                              
       IF #NAME NE ' '                                 
         FIND PERS-VIEW WITH NAME = #NAME              
           IF NO RECORDS FOUND                         
             REINPUT 'PLEASE TRY ANOTHER NAME.'        
           END-NOREC                                   
           /*                                          
           WRITE USING MAP 'MAP002'                    
           /*                                          
         END-FIND                                      
       END-IF
     END-IF  
     /*      
   END-REPEAT
   END

5. Wenn Sie alle Änderungen durchgeführt haben, setzen Sie am Eingabeaufforderungszeichen (>) des Programm-Editors das folgende Kommando ab:

   STOW

   Das Source-Objekt PROG002 wird aktualisiert und ein katalogisiertes Objekt wird in der aktuellen Natural-Library in der aktuellen Systemdatei gespeichert.

Um das Programm PROG002 auszuführen:

1. Geben Sie am Eingabeaufforderungszeichen (>) des Programm-Editors Folgendes ein:

   PROG002

2. Die Ausführung des Programms beginnt und die Maske MAP001 erscheint.

3. Geben Sie den Namen JONES ein und lassen Sie das zweite Eingabefeld leer:

4. Drücken Sie Enter.

   Für die vom Programm erzeugte Liste wird nun die Maske MAP002 benutzt:

   Page 1 07-12-14 17:12:41 NAME: JONES VIRGINIA CITY: TULSA NAME: JONES MARSHA CITY: MOBILE NAME: JONES ROBERT CITY: MILWAUKEE NAME: JONES LILLY CITY: BEVERLEY HILLS NAME: JONES EDWARD CITY: CAMDEN NAME: JONES MARTHA CITY: KALAMAZOO NAME: JONES LAUREL CITY: BALTIMORE NAME: JONES KEVIN CITY: DERBY NAME: JONES GREGORY CITY: NOTTINGHAM

5. Drücken Sie Enter.

   Die Maske MAP001 erscheint:

6. Lassen Sie den Namen JONES stehen und geben Sie die Stadt DERBY ein.

7. Drücken Sie Enter.

   Für die vom Programm erzeugte Liste wird nun die Maske MAP003 benutzt:

   Page 2 07-12-14 17:15:18 THE FOLLOWING EMPLOYEES LIVE IN DERBY NAME: JONES FIRST NAME: KEVIN

8. Drücken Sie Enter.

   Die Maske MAP001 erscheint:

9. Geben Sie an der ersten Stelle des Eingabefeldes NAME einen Punkt ein.

   Das Menü Edit Map erscheint.

Sie haben das Tutorial erfolgreich abgeschlossen.