Z-INF13

Dieses Dokument behandelt die folgenden Themen:

Beschreibung

Die Information für ein bestimmtes Fach oder für einen bestimmten Ordner ausgeben. Dieses Subprogramm bietet auch die Möglichkeit, die Suchbegriffe und die Beschreibung eines Fachs oder Ordners zu ändern.

Um die Information für ein bestimmtes Fach auszugeben, müssen Sie entweder den Fachnamen oder die ISN des Fachs angeben. Sie dürfen nicht beides zusammen angeben.

Um die Information für einen bestimmten Ordner auszugeben, müssen Sie entweder die Namen (Fachname und Ordnername) oder die ISN des Ordners angeben. Sie dürfen nicht beides zusammen angeben.

Wenn Sie im Parameter Befehl den Wert U angeben, können Sie neue Suchbegriffe und eine neue Beschreibung eingeben und anschließend die Fach-/Ordnerinformation ausgeben. Wenn Sie keinen Suchbegriff angeben, werden alle vorher definierten Suchbegriffe gelöscht. Wenn Sie mindestens einen Suchbegriff eingeben, werden alle vorher definierten Suchbegriffe ebenfalls gelöscht. Um die vorher definierten Suchbegriffe beizubehalten, müssen Sie sie daher erneut definieren.

Wenn Sie im Parameter Befehl den Wert R angeben, wird die Fach-/Ordnerinformation ausgegeben. Sie können keine neuen Suchbegriffe und keine neue Beschreibung definieren. Bestehende Suchbegriffe werden nicht gelöscht.

Wenn Sie im Parameter Objekte einen Wert angeben, der kleiner als 1 ist, wird die Anzahl der Objekte in dem Fach oder Ordner nicht ausgegeben.

Wenn Sie im Parameter Objekte einen Wert angeben, der größer oder gleich 1 ist, legen Sie eine obere Grenze fest. In diesem Fall wird die Anzahl der Objekte, die in dem Fach oder Ordner abgelegt sind, im Parameter Objekte ausgegeben. Wenn die Anzahl der Objekte größer als die von Ihnen definierte Obergrenze ist, wird der von Ihnen definierte Wert zusammen mit der Bezeichnung "+1" ausgegeben (wenn Sie zum Beispiel 300 als Obergrenze definiert haben, wird "300+1" ausgegeben).

Die Werte, die für Datum und Zeit ausgegeben werden, basieren auf GMT.

Parameter

Parameter Format Ein Aus Bemerkung
Return-Code N2 O X Eingabe -1: kein ET.
Buero A8 E   Das Büro, in dem sich das Fach befindet, für das Sie die Information ausgeben wollen.
Passwort A8 E   Das Passwort des o.g. Büros.
Fachname A15 E* X Eingabe: entweder der Name des Fachs, für das Sie die Information ausgeben wollen, oder dessen ISN; nicht beides.
Ordnername A15 O X Eingabe: entweder der Name des Ordners im o.g. Fach, für den Sie die Information ausgeben wollen, oder dessen ISN; nicht beides.
ISN P10 E* X Eingabe: entweder die ISN des Fachs oder des Ordners. Für ein Fach: entweder ISN oder Fachname, nicht beides. Für einen Ordner: entweder ISN oder Ordnername, nicht beides.
Befehl A1 E   R=Fach-/Ordnerinformation ausgeben. U=Suchbegriffe aktualisieren und Fach-/Ordnerinformation ausgeben
Suchbegriffe A15/1:6 O X Sie können nur dann Suchbegriffe definieren, wenn Sie den Wert U im Parameter Befehl angeben. Sie können bis zu 6 Suchbegriffe eingeben. Ein Suchbegriff darf keinen Stern (*) enthalten.
Beschreibung A60/1:2 O X Eine kurze Beschreibung für das Fach oder den Ordner. Bei einem Ordner hat die Beschreibung nur eine Zeile und kann bis zu 40 Zeichen lang sein (A40).
Objekte P10 O X Siehe die Beschreibung oben.
Erstellungsdatum P8   X Das Datum, an dem das Fach erstellt wurde.
Erstellungszeit P4   X Die Zeit, zu der das Fach erstellt wurde.
Erstellungskennzeichen A8   X Das Teilnehmerkennzeichen der Person, die das Fach erstellt hat.
Aenderungsdatum P8   X Das Datum, an dem das Fach zuletzt geändert wurde.
Aenderungszeit P4   X Die Uhrzeit, zu der das Fach zuletzt geändert wurde.
Aenderungskennzeichen A8   X Das Teilnehmerkennzeichen der Person, die das Fach zuletzt geändert hat.

Return-Codes

00 Erfolg
02 Ungültiger Büroname oder - nur im Batch-Betrieb - Büro gesperrt
03 Falsches Passwort
04 ISN wurde nicht gefunden
08 Geben Sie entweder ISN oder Name ein - nicht beides
09 ISN zeigt nicht auf das richtige Objekt
51 Ungültiger Name
53 Das gewünschte Objekt existiert nicht
54 Mindestens ein Suchbegriff war ungültig
90 Im Parameter Befehl wurde ein ungültiger Wert eingegeben

Subprogramme

Z-120
Z-122
Z-175
Z-1200&0

Beispiel

0010 DEFINE DATA
0020 *
0030 LOCAL
0040 *
0050 1 RETURN-CODE               (N2)
0060 1 BUERO                     (A8)
0070 1 PASSWORT                  (A8)
0080 1 FACHNAME                  (A15)
0090 1 ORDNERNAME                (A15)
0100 1 ISN                       (P10)
0110 1 BEFEHL                    (A1)
0120 1 SUCHBEGRIFFE              (A15/1:6)
0130 1 BESCHREIBUNG              (A60/1:2)
0140 1 OBJEKTE                   (P10)
0150 1 ERSTELLUNGSDATUM          (P8)
0160 1 ERSTELLUNGSZEIT           (P4)
0170 1 ERSTELLUNGSKENNZEICHEN    (A8)
0180 1 AENDERUNGSDATUM           (P8)
0190 1 AENDERUNGSZEIT            (P4)
0200 1 AENDERUNGSKENNZEICHEN     (A8)
0210 1 #OBJEKT-LESEN             (A1)  INIT <'R'>
0220 1 #OBJEKT-AKTUALISIEREN     (A1)  INIT <'U'>
0230 1 #GRENZE                   (P10) INIT <300>
0240 1 #OBJEKTE                  (A4)
0250 1 #AKTUALISIEREN            (A1)
0260 *
0270 END-DEFINE
0280 *
0290 INPUT (IP=OFF AD=A'_')
0300         'Buero       ' BUERO
0310      /  'Passwort    ' PASSWORT (AD=N)
0320      /  'Fach        ' FACHNAME
0330      /  'Ordner      ' ORDNERNAME
0340 *
0350 * Fach/Ordner lesen
0360 *
0370 MOVE #OBJEKT-LESEN             TO BEFEHL
0380 MOVE #GRENZE                   TO OBJEKTE
0390 PERFORM FACHINFO
0400 IF   RETURN-CODE EQ 0
0410      IF   OBJEKTE GT #GRENZE
0420           COMPRESS '>' #GRENZE INTO #OBJEKTE LEAVING NO SPACE
0430      ELSE
0440           MOVE OBJEKTE         TO #OBJEKTE
0450      END-IF
0460      INPUT NO ERASE (AD=M'_' IP=OFF)
0470           // 15X FACHNAME (AD=O)
0480           /  15X ORDNERNAME (AD=O)
0490           // 'Anzahl der Objekte          ' #OBJEKTE (AD=O)
0500           /  'Suchbegriffe                ' SUCHBEGRIFFE (1:3)
0510           /  15X SUCHBEGRIFFE (4:6)
0520           /  'Beschreibung                ' BESCHREIBUNG (1)
0530           // 'Zum Aktualisieren markieren ' #AKTUALISIEREN
0540 * Suchbegriffe und Beschreibung aktualisieren
0550 *
0560      IF   #AKTUALISIEREN NE ' '
0570           MOVE #OBJEKT-AKTUALISIEREN TO BEFEHL
0580           RESET OBJEKTE
0590           PERFORM FACHINFO
0600           IF   RETURN-CODE EQ 0
0610                WRITE 'Information wurde aktualisiert'
0620           ELSE
0630                WRITE 'Information wurde nicht aktualisiert:' RETURN-CODE
0640           END-IF
0650      END-IF
0660 ELSE
0670      WRITE 'Fach oder Ordner kann nicht bearbeitet werden:' RETURN-CODE
0680 END-IF
0690 *
0700 DEFINE SUBROUTINE FACHINFO
0710 *
0720 IF   ISN NE 0
0730      RESET FACHNAME ORDNERNAME
0740 END-IF
0750 CALLNAT 'Z-INF13'
0760      RETURN-CODE
0770      BUERO
0780      PASSWORT
0790      FACHNAME
0800      ORDNERNAME
0810      ISN
0820      BEFEHL
0830      SUCHBEGRIFFE (*)
0840      BESCHREIBUNG (*)
0850      OBJEKTE
0860      ERSTELLUNGSDATUM
0870      ERSTELLUNGSZEIT
0880      ERSTELLUNGSKENNZEICHEN
0890      AENDERUNGSDATUM
0900      AENDERUNGSZEIT
0910      AENDERUNGSKENNZEICHEN
0920 *
0930 END-SUBROUTINE
0940 END