Z-DETACH

Dieses Dokument behandelt die folgenden Themen:

Beschreibung

Begleitschreiben, Anlagen oder Notizen von einem Dokument entfernen. Oder Notizen von einem Termin oder einer Besprechung entfernen.

Parameter

Parameter Format Ein Aus Bemerkung
Return-Code N2 O X Eingabe -1: kein ET.
Buero A8 E   Das Büro, in dem das Dokument, der Termin oder die Besprechung enthalten ist.
Passwort A8 E   Das Passwort des o.g. Büros.
Befehl A1 E   Muss einer der Folgenden sein: D=entfernen, E=löschen.
Texttyp A1 E   Nur bei Dokumenten erforderlich. Der Typ des zu entfernenden Objekts: C=Begleitschreiben, E=Anlage, N=Notiz.
Aktueller-Texttyp P3 E*   Die Sequenznummer des zu entfernenden Objekts (Begleitschreiben, Anlage oder Notiz). Muss für jeden Texttyp separat angegeben werden. Sie dürfen nur einen der folgenden Parameter angeben: Aktueller-Texttyp, Notizbetreff oder Anlagen-ISN.
Notizbetreff A32 E*   Gilt nur für Notizen. Der Betreff der zu entfernenden Notiz. Sie dürfen nur einen der folgenden Parameter angeben: Aktueller-Texttyp, Notizbetreff oder Anlagen-ISN.
Anlagen-ISN P10 E* X Eingabe: die ISN des zu entfernenden Objekts (Begleitschreiben, Anlage oder Notiz). Vor dem Aufruf dieses Subprogramms können Sie Z-GET11D aufrufen, um die ISN auszugeben. Sie dürfen nur einen der folgenden Parameter angeben: Aktueller-Texttyp, Notizbetreff oder Anlagen-ISN. Ausgabe: Die ISN des entfernten Objekts.
Hauptobjektnummer N2 E   Die Nummer des Objekts, von dem das Begleitschreiben, die Anlage oder Notiz entfernt werden soll. Muss eine der folgenden sein: 3=Termin, 11=Dokument, 16=Besprechung.
Hauptobjektname A32 E*   Nur bei Dokumenten erforderlich. Der Name des Dokuments, von dem das Begleitschreiben, die Anlage oder Notiz entfernt werden soll. Entweder Hauptobjektname oder Hauptobjekt-ISN, nicht beides.
Hauptobjekt-ISN P10 E* X Eingabe: die ISN des Objekts, von dem das Begleitschreiben, die Anlage oder Notiz entfernt werden soll. Bei einem Termin oder einer Besprechung ist dieser Parameter erforderlich. Bei einem Dokument müssen Sie entweder Hauptobjekt-ISN oder Hauptobjektname angeben, nicht beides. Ausgabe: die ISN des Objekts, von dem das Begleitschreiben, die Anlage oder Notiz entfernt wurde.

Return-Codes

00 Erfolg
02 Ungültiger Büroname
03 Falsches Passwort
04 Hauptobjekt-ISN wurde nicht gefunden
08 Geben Sie entweder ISN oder Name des Hauptobjekts ein - nicht beides
09 Hauptobjekt-ISN zeigt nicht auf Dokument, Termin oder Besprechung
13 Ungültige Hauptobjektnummer
51 Ungültiger Hauptobjektname
53 Das gewünschte Objekt existiert nicht
59 Der gewünschte Befehl (D oder E) wurde nicht gefunden
91 Ungültiger Texttyp
92 Ungültiger Aktueller-Texttyp
93 Begleitschreiben, Anlage oder Notiz existiert nicht
94 Dokument befindet sich nicht im Arbeitsfach oder einem selbstdefinierten Fach
95 Fehler beim Erstellen des separaten (entfernten) Dokuments
96 Geben Sie nur eines an: Aktueller-Texttyp, Notizbetreff oder Anlagen-ISN
97 Ungültiger Notizbetreff

Subprogramme

N-GETMSG
Z-120
Z-122
Z-123
Z-135
Z-161
Z-175
Z-180
Z-711
Z-1200&0

Beispiel

0010 *
0020 * Notiz von Besprechung/Termin entfernen
0030 *
0040 *
0050 DEFINE DATA
0060 *
0070 LOCAL
0080 1 RETURN-CODE        (N2)
0090 1 BUERO              (A8)
0100 1 PASSWORT           (A8)
0110 1 BEFEHL             (A1)     /* D=entfernen, E=loeschen
0120 1 TEXTTYP            (A1)     /* N=Notiz, C=Begleitschreiben,E=Anlage
0130 1 AKTUELLER-TEXTTYP  (N2)     /* Sequenznummer des zu entfernenden Objekts
0140 *                                (separat fuer jeden Typ (N/C/E)).
0150 1 NOTIZBETREFF       (A32)
0160 1 ANLAGEN-ISN        (P10)
0170 1 HAUPTOBJEKTNUMMER  (N2)
0180 1 HAUPTOBJEKTNAME    (A32)
0190 1 HAUPTOBJEKT-ISN    (P10)
0200 * ----------------------------
0210 1 STARTDATUM         (A8)     /* Parameter fuer Z-GET06B
0220 1 STARTZEIT          (A8)
0230 1 ENDDATUM           (A8)
0240 1 ENDZEIT            (A8)
0250 1 BETREFF            (A20)
0260 1 BESCHREIBUNG       (A60/1:3)
0270 1 ORT                (A60)
0280 1 AGENDA             (A32)
0290 1 SUCHBEGRIFFE       (A15/1:6)
0300 1 PERSOENLICH-FLAG   (A1)
0310 1 BERECHTIGUNGSSTUFEN (A1/1:4)
0320 1 OBJEKTNUMMER       (N2)
0330 1 ZEITRAUM           (A1)
0340 1 KEINE-ZEITBELEGUNG (A1)
0350 1 AKTUELLES-DATUM    (A8)
0360 1 AKTUELLER-START    (A8)
0370 1 AKTUELLES-ENDE     (A8)
0380 1 KALENDER-ISN       (P10)    /* ISN des Datensatzes wird ausgegeben
0390 1 NUR-ERSTER-SATZ    (A1)     /* Nur der erste Datensatzes eines Kalender-
0400 *                                eintrags, der ueber mehrere Tage geht
0410 1 NOTIZEN            (N2)     /* Anzahl der Notizen wird ausgegeben
0420 1 WORK-PARAMETER     (A40)
0430 * ----------------------------
0440 1 BESPRECHUNG-GEFUNDEN (L)    INIT < FALSE >
0450 *
0460 END-DEFINE
0470 *
0480 RESET RETURN-CODE
0490 MOVE 'BUERO'    TO BUERO
0500 MOVE 'PASSWORT' TO PASSWORT
0510 MOVE '19971231' TO STARTDATUM
0520 MOVE '2000'     TO STARTZEIT
0530 MOVE 'X'        TO NUR-ERSTER-SATZ
0540 *
0550 REPEAT UNTIL RETURN-CODE NE 0
0560 *
0570   CALLNAT 'Z-GET06B' RETURN-CODE
0580     BUERO
0590     PASSWORT
0600     STARTDATUM
0610     STARTZEIT
0620     ENDDATUM
0630     ENDZEIT
0640     BETREFF
0650     BESCHREIBUNG(*)
0660     ORT
0670     AGENDA
0680     SUCHBEGRIFFE(*)
0690     PERSOENLICH-FLAG
0700     BERECHTIGUNGSSTUFEN(*)
0710     OBJEKTNUMMER
0720     ZEITRAUM
0730     KEINE-ZEITBELEGUNG
0740     AKTUELLES-DATUM
0750     AKTUELLER-START
0760     AKTUELLES-ENDE
0770     KALENDER-ISN
0780     NUR-ERSTER-SATZ
0790     NOTIZEN
0800     WORK-PARAMETER
0810   IF KALENDER-ISN NE 0
0820       AND  STARTDATUM EQ '19971231'
0830       AND  STARTZEIT  EQ '    2000'
0840       AND  BETREFF EQ 'BESPRECH-BETREFF'
0850     MOVE TRUE TO BESPRECHUNG-GEFUNDEN
0860     ESCAPE BOTTOM     /* Gehe zur zu entfernenden Notiz
0870   END-IF
0880 END-REPEAT
0890 *
0900 IF BESPRECHUNG-GEFUNDEN
0910   MOVE 'D'            TO BEFEHL
0920   MOVE 'N'            TO TEXTTYP
0930   MOVE 'Besprechungsnotizen' TO NOTIZBETREFF
0940   MOVE  16            TO HAUPTOBJEKTNUMMER  /* Besprechung
0950   MOVE  KALENDER-ISN  TO HAUPTOBJEKT-ISN    /* Mit Z-GET06B gefundene ISN
0960   CALLNAT 'Z-DETACH'
0970     RETURN-CODE
0980     BUERO
0990     PASSWORT
1000     BEFEHL
1010     TEXTTYP
1020     AKTUELLER-TEXTTYP
1030     NOTIZBETREFF
1040     ANLAGEN-ISN
1050     HAUPTOBJEKTNUMMER
1060     HAUPTOBJEKTNAME
1070     HAUPTOBJEKT-ISN
1080 *
1090   IF RETURN-CODE EQ 00 OR EQ -1
1100     WRITE 'Notiz wurde entfernt'  /
1110     WRITE 'ISN des erstellten Dokuments ' ANLAGEN-ISN
1120   ELSE
1130     WRITE 'Return-Code ' RETURN-CODE  /
1140   END-IF
1150 ELSE
1160   WRITE 'Besprechung wurde nicht gefunden'
1170 END-IF
1180 *
1190 END