DOWNLOAD PC FILE

#### Search Results

Search

# DOWNLOAD PC FILE

| `DOWNLOAD` |  |  | `PC` |  | [`FILE`] work-file-number |  | [`VARIABLE`] operand1 [(parameter)] |
`WRITE` | `WORK` | `COMMAND` operand2 |  | `SYNC` |
`ASYNC`

Dieses Dokument behandelt folgende Themen:

- Funktion DOWNLOAD PC FILE

- Syntax-Beschreibung DOWNLOAD PC FILE

- Externe Darstellung der Felder

- Beispiele DOWNLOAD PC FILE

Eine Erläuterung der in dem Syntax-Diagramm verwendeten Symbole entnehmen Sie dem Abschnitt Syntax-Symbole.

Verwandte Statements: `CLOSE PC FILE` | `UPLOAD PC FILE` | `WRITE WORK FILE`

## Funktion DOWNLOAD PC FILE

Dieses Statement dient dazu, Daten zum PC zu übertragen.

Siehe auch die Natural Connection-Dokumentation und die Entire Connection-Dokumentation

## Syntax-Beschreibung DOWNLOAD PC FILE

Operanden-Definitionstabelle:

Operand | Mögliche Struktur | Mögliche Formate | Referenzierung erlaubt | Dynam. Definition
--- | --- | --- | --- | ---
operand1 | C | S | A | G |  | A | U | N | P | I | F | B | D | T | L | C | ja | nein
operand2 | C | S |  |  |  | A |  |  |  |  |  |  |  |  |  |  | ja | ja

Die Formate C und G sind bei Natural Connection nicht gültig.

Syntax-Element-Beschreibung:

Syntax-Element | Beschreibung
--- | ---
`work-file-number` | Zu benutzende Arbeitsdateinummer: Diese Nummer muss der Nummer unter den Arbeitsdateinummern für den PC entsprechen, wie sie in Natural definiert sind.
`VARIABLE` | Format: Die Datensätze in der PC-Datei werden in variablem Format geschrieben. Beachten Sie, dass variable Datensätze nicht in PC Spreadsheet-Formate konvertiert werden können.
`operand1` | Feld-Spezifikation: Mit operand1 geben Sie die Felder an, die zum PC heruntergeladen werden sollen.
`COMMAND` | COMMAND-Klausel: Mit dieser Klausel können Sie PC-Kommandos (d.h. Kommandos, die in die Kommandozeile von Entire Connection auf dem PC eingegeben werden können) zum PC senden. Entire Connection überprüft, ob das gesendete Kommando gültig ist oder nicht. Ein Kommando, das vom PC nicht erkannt werden kann, wird zurückgewiesen. In diesem Fall gibt Natural eine Fehlermeldung mit dem Inhalt aus, dass das heruntergeladene Kommando vom PC zurückgewiesen wurde. Sie können die `COMMAND`-Klausel benutzen, um zum Beispiel Entire Connection-Tasks von einem z/OS-Computer aus auszuführen. Wenn Sie die Task `DIR` haben, die PC Directory-Informationen anzeigt, können Sie diese direkt aus Ihrem Natural-Programm heraus auf einem z/OS-Computer mit dem folgenden Statement anstoßen:
    DOWNLOAD PC FILE 7 COMMAND 'DIR'
In Beispiel 2 weiter unten wird die `COMMAND`-Klausel benutzt, um den Namen der PC-Datei zu definieren, die die heruntergeladenen Daten aufnehmen soll. Auf diese Art können Sie die Eingabeaufforderung nach dem Namen der Datei umgehen.
`operand2` | COMMAND-Spezifikation: Mit operand2 geben Sie das DOS-Kommando oder die Entire Connection-Task an, die auf dem PC ausgeführt werden soll. operand2 muss eine alphanumerische Konstante oder Variable sein.
`SYNC` | SYNC-Option: Mit `SYNC` geben Sie an, dass der PC nach Ausführen und Beenden von `COMMAND` die Kontrolle an Natural zurückgibt. `SYNC` kann benutzt werden, um zum Beispiel sicherzustellen, dass das Kommando `SET PCFILE` ausgeführt worden ist, bevor eine Datei-Übertragung startet.
`ASYNC` | A SYNC-Option: Mit `ASYNC` legen Sie fest, dass der PC die Kontrolle sofort an Natural zurückgibt, unabhängig davon, ob die Ausführung von `COMMAND` beendet wurde oder nicht.
parameter | Editiermaske-Parameter: Als `parameter` können Sie den Session-Parameter `EM` oder `EMU` angeben:
`EM=` | Editiermaske Einzelheiten zu Editiermasken finden Sie unter dem Session-Parameter `EM` in der Parameter-Referenz-Dokumentation. Der `EM`-Parameter kann nicht bei Gruppenoperanden angewendet werden.
`EMU=` | Unicode-Editiermaske Einzelheiten zu Editiermasken finden Sie unter dem Session-Parameter `EMU` in der Parameter-Referenz-Dokumentation. Der `EMU`-Parameter kann nicht bei Gruppenoperanden angewendet werden.

## Externe Darstellung der Felder

In der externen Datei werden Felder, die mit einem `DOWNLOAD PC FILE`-Statement geschrieben werden, entsprechend ihrer internen Definition dargestellt, es sei denn, es wird eine Editiermaske angewendet.

- Felder ohne Eingabemasken

- Felder mit Eingabemasken

### Felder ohne Eingabemasken

Bei Feldern ohne Editiermasken werden die Feldwerte nicht bearbeitet, sondern in ihrem internen Format geschrieben.

- Format A und B
  Die Anzahl der Bytes in der externen Datei entspricht der im Natural-Programm definierten internen Länge. Es erfolgt keine Bearbeitung und der Wert enthält kein Dezimalzeichen.

- Format N
  Die Anzahl der Bytes in der externen Datei entspricht der Summe der internen Stellen vor und nach dem Dezimalzeichen. Das Dezimalzeichen ist in der Ausgabe nicht enthalten.

- Format P
  Die Anzahl der Bytes in der externen Datei entspricht der Summe der Stellen vor und nach dem Dezimalzeichen, plus 1 für das Vorzeichen, geteilt durch 2 und aufgerundet auf das nächste volle Byte.

Anmerkung
Bei Feldern, die ohne Editiermaske geschrieben werden, wird keine Formatkonvertierung durchgeführt.

Beispiele für Felddarstellung (ohne Eingabemasken)

Felddefinition | Ausgabelänge
--- | ---
#FIELD1 (A10) | 10 Bytes
#FIELD2 (B15) | 15 Bytes
#FIELD3 (N1.3) | 4 Bytes
#FIELD4 (N0.7) | 7 Bytes
#FIELD5 (P1.2) | 2 Bytes
#FIELD6 (P6.0) | 4 Bytes

### Felder mit Eingabemasken

Bei Anwendung einer Editiermaske wird das Feld zunächst gemäß der angegebenen Editiermaske formatiert, und der resultierende formatierte Wert wird in die Arbeitsdatei geschrieben.

- In diesem Fall wird die interne Darstellung nicht verwendet.

- Die Länge des in die Datei geschriebenen Wertes entspricht der Länge der resultierenden formatierten Zeichenkette.

## Beispiele DOWNLOAD PC FILE

- Beispiel 1 — Benutzung des Statements DOWNLOAD PC FILE

- Beispiel 2 — Benutzung der COMMAND-Klausel

- Beispiel 3 — DOWNLOAD PC FILE mit Editiermaske

### Beispiel 1 — Benutzung des Statements DOWNLOAD PC FILE

Das folgende Programm veranschaulicht die Benutzung des Statements `DOWNLOAD PC FILE`. Die Daten werden zunächst selektiert und dann mittels Arbeitsdatei `PC FILE 7` zum PC heruntergeladen.

    ** Example 'PCDOEX1': DOWNLOAD PC FILE
    **
    ** NOTE: Example requires that Natural Connection is installed.
    ************************************************************************
    DEFINE DATA LOCAL
    01 PERS VIEW OF EMPLOYEES
      02 PERSONNEL-ID
      02 NAME
      02 CITY
    END-DEFINE
    *
    FIND PERS WITH CITY = 'NEW YORK'                     /* Data selection
      DOWNLOAD PC FILE 7 CITY NAME PERSONNEL-ID    /* Data download
    END-FIND
    END

Ausgabe des Programms `PCDOEX1`:

Wenn Sie das Programm starten, erscheint ein Fenster, in dem Sie den Namen der PC-Datei angeben, in die die Daten heruntergeladen werden sollen. Die Daten werden dann auf den PC heruntergeladen.

### Beispiel 2 — Benutzung der COMMAND-Klausel

Das folgende Programm veranschaulicht die Benutzung der `COMMAND`-Klausel im Statement `DOWNLOAD PC FILE`. Der Name der empfangenden PC-Datei wird als erstes definiert. Dann werden die Daten selektiert und auf diese Datei heruntergeladen.

    ** Example 'PCDOEX2': DOWNLOAD PC FILE
    **
    ** NOTE: Example requires that Natural Connection is installed.
    ************************************************************************
    DEFINE DATA LOCAL
    01 PERS VIEW OF EMPLOYEES
      02 PERSONNEL-ID
      02 NAME
      02 CITY
    01 CMD (A80)                                   /* Variable for transfer
    END-DEFINE                                     /* of the PC command
    *
    MOVE 'SET PCFILE 7 DOWN DATA PERS.NCD' TO CMD  /* PC command to define
    *
    DOWNLOAD PC FILE 6 COMMAND CMD                 /* Command download
    *
    FIND PERS WITH CITY = 'NEW YORK'               /* Data selection
      DOWNLOAD PC FILE 7 CITY NAME PERSONNEL-ID    /* Data download
    END-FIND
    END

Anmerkung
Die PC-Dateinummern in zwei aufeinanderfolgenden `DOWNLOAD PC FILE`-Statements müssen sich unterscheiden.

Ausgabe des Programms `PCDOEX2`:

Wenn Sie das Programm starten, werden die Daten zu der PC-Datei heruntergeladen, die im Programm angegeben wurde. Ein Fenster erscheint nicht.

### Beispiel 3 — DOWNLOAD PC FILE mit Editiermaske

Das folgende Programm veranschaulicht die Benutzung des Statement `DOWNLOAD PC FILE`. Die Daten werden zunächst ausgewählt und dann unter Verwendung der Arbeitsdatei 6 auf den PC heruntergeladen.

    ** Example 'PCDOEX3': DOWNLOAD PC FILE with Edit Mask
    **
    ** NOTE: Example requires that Natural Connection is installed.
    ************************************************************************
    DEFINE DATA LOCAL
    1 EMPLOY-VIEW VIEW OF EMPLOYEES
      2 PERSONNEL-ID
      2 NAME
      2 CITY
      2 BIRTH
    END-DEFINE
    *
    FIND EMPLOY-VIEW WITH CITY = 'MADRID'
      DOWNLOAD PC FILE 6
            PERSONNEL-ID NAME BIRTH (EM=YYYY/MM/DD)
    END-FIND

Ausgabe des Programms `PCDOEX3`:

Wenn Sie das Programm ausführen, werden die Daten in die im Programm angegebene PC-Datei heruntergeladen. Es wird kein Fenster angezeigt.

### On this page

- Funktion DOWNLOAD PC FILE
- Syntax-Beschreibung DOWNLOAD PC FILE
- Externe Darstellung der Felder
- Beispiele DOWNLOAD PC FILE