Querying for alarms

integer reqId := com.apama.cumulocity.Util.generateReqId();

com.apama.cumulocity.FindAlarm request := new com.apama.cumulocity.FindAlarm;
request.reqId := reqId;

// Filter based on alarms type
request.params.add("type", "c8y_UnavailabilityAlarm");

// Subscribe to com.apama.cumulocity.FindAlarmResponse.SUBSCRIBE_CHANNEL to listen
// for responses
monitor.subscribe(com.apama.cumulocity.FindAlarmResponse.SUBSCRIBE_CHANNEL);

// Listen for responses based on reqId
on all com.apama.cumulocity.FindAlarmResponse(reqId=reqId) as response
// Avoid listener leaks by terminating the listener on completion of the request
and not com.apama.cumulocity.FindAlarmResponseAck(reqId=reqId)
{
log "Received Alarm " + response.toString() at INFO;
}

// Listen for com.apama.cumulocity.FindAlarmResponseAck,
// this indicates that all responses have been received
on com.apama.cumulocity.FindAlarmResponseAck(reqId=reqId) as requestCompleted
{
log "Received all Alarm(s) for request " +
requestCompleted.reqId.toString() at INFO;

// Request is completed and we can unsubscribe from this channel
monitor.unsubscribe(com.apama.cumulocity.FindAlarmResponse.SUBSCRIBE_CHANNEL);
}

// Send request to find available alarms
send request to com.apama.cumulocity.FindAlarm.SEND_CHANNEL;

Parameter	Description
id	Search for an alarm based on alarmId. When searching for an alarm based on Id, all the query parameters listed below are ignored.
source	Search for alarms based on the device identifier or asset identifier of the source.
status	Search for alarms based on the status. The status can be any of ACTIVE, ACKNOWLEDGED or CLEARED.
severity	Search for alarms based on the severity. The severity can be any of CRITICAL, MAJOR, MINOR or WARNING.
type	Search for alarms based on the type.
dateFrom	Search for alarms from a start date. The date and time is provided as seconds since the epoch.
dateTo	Search for alarms within a time range. This is to be used in combination with dateFrom. The date and time is provided as seconds since the epoch.
resolved	A boolean parameter used for filtering, based on the resolved state.
pageSize	Indicates how many entries of the collection are to be retrieved from Cumulocity IoT. This is a batching parameter for getting multiple responses from Cumulocity IoT. A larger pageSize does fewer requests to Cumulocity IoT to retrieve all the alarms, but each request is larger. By default, 1000 alarms are in each page and there is an upper limit of 2000.
currentPage	Retrieve a specific page of results for the given pageSize. If currentPage is set, then only a single page is requested. If currentPage is not set (default), all the pages are requested.